Softwareverteilung mit einem VBS Script

Diese Seite verwendet Cookies. Durch die Nutzung unserer Seite erklären Sie sich damit einverstanden, dass wir Cookies setzen. Weitere Informationen

  • Softwareverteilung mit einem VBS Script

    Anwendungszweck
    Das Softwareverteilungsskript (VBScript) kann zur automatisierten Installation/Aktualisierung von Anwendungen benutzt werden. Es unterstützt ebenfalls die Installation/Aktualisierung aufgrund von Gruppenzugehörigkeiten der Active Directory Computerkonten benutzt werden. Grundsätzlich kann jede Software damit verteilt werden, solange diese sogenannte Silent Parameter unterstützt. Funktioniert für MSI Pakete oder EXE Installationen.


    Erklärungen Parameter
    Grundsätzlich sind alle Funktionen innerhalb des Skripts dokumentiert. Ebenfalls befinden sich bereits einige Demoinstallationen im Skript. Damit die Softwareinstallationen über den Systemaccount des Computers aufgerufen werden können, müssen die Benutzer „NETZWERK, NETZWERKDIENST und SYSTEM“ Zugriffsrechte auf der Freigabe und im NTFS System erhalten.

    Sub Install_Software
    Die Prozedur „Install_Software“ ist für die eigentliche Software Installation zuständig. Die Prozedur muss mit folgenden Parametern aufgerufen werden: Install_Software (Name, Version, Command, RegistryKey)

    Name
    Der Name der zu installierenden Software (dient nur zu Anzeigezwecken im Eventlog).

    Version
    Die korrekte Versionsnummer der zu installierenden Version, welche exakt aus der Registry eines Testclients ausgelesen werden muss.

    Command
    Der auszuführende Installationsbefehl mit allen Parameters (Silent Installation etc.).

    RegistryKey
    Der Registryeintrag, welcher die Versionsnummer der bereits installierten Software beinhaltet.
    Beispiel:
    Install_Software "AdobeReaderXI", "4.2.2579", "msiexec.exe /i " & Chr(34) & "\\servername.intra\DFSroot\Deploy\officeatwork\officeatwork Client Suite.msi" & Chr(34) & " /qn", “HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{243369B6-A51D-46F8-B242-6AC2595558CD}\DisplayVersion"

    Aufgrund des obenstehenden Aufrufs prüft die Prozedur „Install_Software“ den mitgelieferten Registryeintrag. Ist dieser vorhanden, wird dessen Inhalt mit der Versionsnummer verglichen. Ist die Versionsnummer im Registryeintrag tiefer als diejenige, welche als Parameter mitgegeben wird, wird der Installationsbefehl ausgeführt.
    Ist der Registryeintrag nicht vorhanden, wird der Installationsbefehl ebenfalls ausgeführt.

    Anpassungen sind am Skript nötig
    Grundsätzlich muss für jede Software, welche auf allen Computern installiert werden soll, eine Prozedur analog der Beispiele im Skript erstellt werden. Soll eine Software nur auf bestimmten Computern installiert werden, muss eine Sicherheitsgruppe im Active Directory erstellt werden und die entsprechenden Computerkonten darin als Mitglied hinzugefügt werden. Danach muss im Bereich „Run installations depending on group memberships of computers“ eine Abfrage dieser Sicherheitsgruppe eingebaut werden

    Skript aufgerufen
    Das Skript muss als Windows Startup Skript aufgerufen, da dies auf dem Computer und nicht per Benutzer aufgerufen werden muss.

    Code als .vbs Datei speichern

    Brainfuck-Quellcode

    1. '--------------------------------------------------------------------------------------------------------------------
    2. ' Funktion : Software deployment
    3. ' Version : 1.0
    4. ' Beschreibung : Dieses Skript installiert Software basierend auf Gruppenzugehoerigkeiten des Computerkontos
    5. ' Kunde : xxx
    6. '
    7. ' Version 1.0
    8. '
    9. '--------------------------------------------------------------------------------------------------------------------
    11. On Error Resume Next
    13. 'Dim variables
    14. Dim objSysInfo
    15. Dim objComputer
    16. Dim objMemberOf
    17. Dim objConnection
    18. Dim objCommand
    19. Dim objName
    20. Dim objEventLog
    21. Dim strComputerName
    22. Dim strGroup
    23. Dim strEvenlogID
    25. 'Dim contants
    26. Const ADS_SCOPE_SUBTREE = 2
    28. 'Set objects
    29. Set objSysInfo = CreateObject("ADSystemInfo")
    30. Set objEventLog = CreateObject("WScript.Shell")
    32. 'Fill variables
    33. strComputerName = objSysInfo.Computername
    34. strEventlogID = "Software deployment: "
    36. 'Create Active Directory connection
    37. Set objConnection = CreateObject("ADODB.Connection")
    38. Set objCommand = CreateObject("ADODB.Command")
    39. objConnection.Provider = "ADsDSOObject"
    40. objConnection.Open "Active Directory Provider"
    41. Set objCommand.ActiveConnection = objConnection
    42. objCommand.Properties("Page Size") = 10
    43. objCommand.Properties("Timeout") = 30
    44. objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
    45. objCommand.Properties("Cache Results") = False
    46. objName = "LDAP://" & strComputerName
    48. Set objComputer = GetObject(objName)
    50. objEventLog.LogEvent 0, strEventlogID & "Skript gestartet."
    52. 'Check for errors
    53. If Err.Number <> 0 Then
    54. objEventLog.LogEvent 1, strEventlogID & "Fehler " & Err.Number & " (" & Err.Description & ") aufgetreten."
    55. WScript.End
    56. End If
    58. objMemberOf = objComputer.GetEx("memberOf")
    60. 'Run installations for all computers
    62. 'Example installations
    63. 'Example_Install_Greenshot
    64. 'Example_AdobeReaderXI
    65. 'Example_AdobeFlashPlayer
    66. 'Example_Java7
    67. 'Example_AdobeAIR
    69. 'Run installations depending on group memberships of computers
    70. For Each strGroup in objMemberOf
    72. If Instr(strGroup, "sg_softdeploy_") <> 0 Then
    73. Dim strSingleGroup
    74. strSingleGroup = ""
    75. strSingleGroup = Mid(strGroup, Instr(strGroup, "CN=") + 3, Instr(strGroup, ",") -4)
    77. Select Case strSingleGroup
    78. Case "sg_softdeploy_picasa"
    79. 'Example_Install_GooglePicasa
    80. Case "sg_softdeploy_googleearth"
    81. 'Example_Install_GoogleEarth
    82. Case "sg_softdeploy_okpvalidation"
    83. 'Example_Install_OKPValidation
    84. End Select
    85. End If
    87. Next
    89. objEventLog.LogEvent 0, strEventlogID & "Skript beendet."
    91. WScript.Quit
    93. 'Start Picasa installation
    94. Sub Example_Install_GooglePicasa
    96. Install_Software "Picasa", _
    97. "3.9", _
    98. "\\servername.intra\DFSroot\Deploy\picasa\picasa39-setup.exe /S /L", _
    99. "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Picasa 3\DisplayVersion"
    101. End Sub
    103. 'Start Greenshot installation
    104. Sub Example_Install_Greenshot
    106. Install_Software "Greenshot", _
    107. "1.1.7.17", _
    108. "\\servername.intra\DFSroot\Deploy\Greenshot\Greenshot-INSTALLER-1.1.7.17.exe /VERYSILENT /LANG=DE", _
    109. "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Greenshot_is1\DisplayVersion"
    111. End Sub
    113. 'Start Adobe Reader XI installation
    114. Sub Example_Install_AdobeReaderXI
    116. Install_Software "AdobeReaderXI", _
    117. "11.0.06", _
    118. "\\servername.intra\dfsroot\Deploy\AdobeReaderXI\AdbeRdr11006_de_DE.exe /msi EULA_ACCEPT=Yes /qn", _
    119. "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-AB0000000001}\DisplayVersion"
    121. End Sub
    123. 'Start Adobe Flash Player installation
    124. Sub Example_Install_AdobeFlashPlayer
    126. Install_Software "AdobeFlashPlayer", _
    127. "11.9.900.117", _
    128. "\\servername.intra\DFSroot\Deploy\AdobeFlashPlayer11\install_flash_player_11_active_x.exe -install", _
    129. "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Adobe Flash Player ActiveX\DisplayVersion"
    131. End Sub
    133. 'Start Google Earth installation
    134. Sub Example_Install_GoogleEarth
    136. Install_Software "GoogleEarth", _
    137. "7.1.1.1580", _
    138. "msiexec.exe /i " & Chr(34) & "\\servername.intra\DFSroot\Deploy\GoogleEarth\Google Earth.msi" & Chr(34) & " /qn", _
    139. "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{0A844D8F-A965-11E2-9E77-B8AC6F98CCE3}\DisplayVersion"
    141. End Sub
    143. 'Start Java 7 installation
    144. Sub Example_Install_Java7
    146. Install_Software "Java7", _
    147. "7.0.450", _
    148. "msiexec.exe /i \\servername.intra\DFSroot\Deploy\Java\JRE7U45X86\jre1.7.0_45.msi /qn IEXPLORER=1 ALLUSERS=1 JAVAUPDATE=0 AUTOUPDATECHECK=0", _
    149. "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{26A24AE4-039D-4CA4-87B4-2F83217045FF}\DisplayVersion"
    151. End Sub
    153. 'Start Adobe AIR installation
    154. Sub Example_Install_AdobeAIR
    156. Install_Software "AdobeAIR", _
    157. "3.7.0.1860", _
    158. "\\servername.intra\DFSroot\Deploy\AdobeAIR\AdobeAIRInstaller.exe -silent", _
    159. "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{A0087DDE-69D0-11E2-AD57-43CA6188709B}\DisplayVersion"
    161. End Sub
    163. 'Installation routine
    164. Sub Install_Software(Name, Version, Command, RegistryKey)
    166. 'Dim variables
    167. Dim strSoftware
    168. Dim strVersion
    170. 'Set values into variables
    171. strSoftware = Name
    172. strVersion = Version
    174. 'Check if version in registry is lower or missing
    175. If Read_Registry(RegistryKey) < strVersion Or Read_Registry(RegistryKey) = "Missing" Then
    177. On Error Resume Next
    179. 'Start installation
    180. Dim objShell
    181. Dim objEnv
    182. Set objShell = CreateObject("WScript.Shell")
    183. Set objEnv = objShell.Environment("PROCESS")
    185. objEnv("SEE_MASK_NOZONECHECKS") = 1
    186. objShell.Run Command, 0, True
    187. objEnv.Remove("SEE_MASK_NOZONECHECKS")
    189. 'Check for errors during installation routine
    190. If Err.Number <> 0 Then
    192. objEventLog.LogEvent 1, strEventlogID & "Fehler " & Err.Number & " (" & Err.Description & ") beim Installieren von " & Name & " Version " & Version & " aufgetreten."
    193. Err.Number = 0
    195. End If
    197. End If
    199. End Sub
    201. 'Function to read registry values
    202. Function Read_Registry(RegKey)
    204. On Error Resume Next
    206. Dim objRegistryShell
    207. Dim strReturn
    208. Set objRegistryShell = CreateObject("WScript.Shell")
    210. Read_Registry = objRegistryShell.RegRead(RegKey)
    212. If Err.Number <> 0 Then
    213. objEventLog.LogEvent 1, strEventlogID & "Fehler " & Err.Number & " (" & Err.Description & ") beim Lesen von Key " & RegKey & " aufgetreten."
    214. Read_Registry = "Missing"
    215. End If
    217. End Function
    Alles anzeigen


    Wenn "Server" eine Religion ist, haben wir die passende Kathedrale dazu!
    Mehr Infos unter www.fsit.com oder Facebook